The D programming language. Modern convenience. Modeling power. Native efficiency.

#!/usr/bin/rdmd
// Computes average line length for standard input.
import std.stdio;

void main() {
    ulong lines = 0;
    double sumLength = 0;
    foreach (line; stdin.byLine()) {
        ++lines;
        sumLength += line.length;
    }
    writeln("Average line length: ",
        lines ? sumLength / lines : 0);
}

D is a language with C-like syntax and static typing. It pragmatically combines efficiency, control, and modeling power, with safety and programmer productivity.

Convenience

• D allows writing large code fragments without redundantly specifying types, like dynamic languages do. On the other hand, static inference deduces types and other code properties, giving the best of both the static and the dynamic worlds.

  void main() {
      // Define an array of numbers, double[]. Compiler recognizes the common
      // type of all initializers.
      auto arr = [ 1, 2, 3.14, 5.1, 6 ];
      // Dictionary that maps string to int, type is spelled int[string]
      auto dictionary = [ "one" : 1, "two" : 2, "three" : 3 ];
      // Calls the min function defined below
      auto x = min(arr[0], dictionary["two"]);
  }
  // Type deduction works for function results. This is important for generic
  // functions, such as min below, which works correctly for all comparable
  // types.
  auto min(T1, T2)(T1 lhs, T2 rhs) {
      return rhs < lhs ? rhs : lhs;
  }
  

• Automatic memory management makes for safe, simple, and robust code. D also supports scoped resource management (aka the RAII idiom) and scope statements for deterministic transactional code that is easy to write and read.

  import std.stdio;
  
  class Widget { }
  
  void main() {
      // Automatically managed.
      auto w = new Widget;
      // Code is executed in any case upon scope exit.
      scope(exit) { writeln("Exiting main."); }
      // File is closed deterministically at scope's end.
      foreach (line; File("text.txt").byLine()) {
          writeln(line);
      }
      writeln();
  }
  

• Built-in linear and associative arrays, slices, and ranges make daily programming simple and pleasant for tasks, both small and large.

  #!/usr/bin/rdmd
  import std.range, std.stdio;
  
  // Compute average line length for stdin
  void main() {
      ulong lines = 0, sumLength = 0;
      foreach (line; stdin.byLine()) {
          ++lines;
          sumLength += line.length;
      }
      writeln("Average line length: ",
          lines ? cast(double) sumLength / lines : 0.0);
  }
  

Power

• The best paradigm is to not impose something at the expense of others. D offers classic polymorphism, value semantics, functional style, generics, generative programming, contract programming, and more—all harmoniously integrated.

  // Interfaces and classes
  interface Printable {
     void print(uint level)
     in { assert(level > 0); } // contract is part of the interface
  }
  
  // Interface implementation
  class Widget : Printable {
     void print(uint level) 
     in{ }
     body{ }
  }
  
  // Single inheritance of state
  class ExtendedWidget : Widget {
     override void print(uint level)
     in { /* weakening precondition is okay */  }
     body {
         //... level may be 0 here ...
     }
  }
  
  // Immutable data shared across threads
  immutable string programName = "demo";
  // Mutable data is thread-local
  int perThread = 42;
  // Explicitly shared data
  shared int perApp = 5;
  
  // Structs have value semantics
  struct BigNum {
      // intercept copying
      this(this) { }
      // intercept destructor
      ~this() { }
  }
  
  void main()
  {
      // ...
  }
  

• D offers an innovative approach to concurrency, featuring true immutable data, message passing, no sharing by default, and controlled mutable sharing across threads. Read more.
• From simple scripts to large projects, D has the breadth to scale with any application's needs: unit testing, information hiding, refined modularity, fast compilation, precise interfaces. Read more.

Efficiency

• D compiles naturally to efficient native code.
• D is designed such that most "obvious" code is fast and safe. On occasion a function might need to escape the confines of type safety for ultimate speed and control. For such rare cases D offers native pointers, type casts, access to any C function without any intervening translation, and even inline assembly code.

  import core.stdc.stdlib;
  
  void livingDangerously() {
      // Access to C's malloc and free primitives
      auto buf = malloc(1024 * 1024);
      scope(exit) free(buf); // free automatically upon scope exit
      // Interprets memory as an array of floats
      auto floats = cast(float[]) buf[0 .. 1024 * 1024];
      // Even stack allocation is possible
      auto moreBuf = alloca(4096 * 100);
      //...
  }
  
  // Using inline asm for extra speed on x86
  uint checked_multiply(uint x, uint y) {
      uint result;
      version (D_InlineAsm_X86) {
          // Inline assembler "sees" D variables.
          asm {
              mov     EAX,x        ;
              mul     EAX,y        ;
              mov     result,EAX   ;
              jc      Loverflow    ;
          }
          return result;
      } else {
          result = x * y;
          if (!y || x <= uint.max / y)
             return result;
     }
  Loverflow:
     throw new Exception("multiply overflow");
  }
  
  void main()
  {
      // ...
  }
  

• The @safe, @trusted, and @system modular attributes allow the programmer to best decide the safety-efficiency tradeoffs of an application, and have the compiler check for consistency. Read more.